625d14d784
git-svn-id: svn+ssh://asterix.ieap.uni-kiel.de/home/subversion/stephan/solo/eda/cospi/host@8348 bc5caf13-1734-44f8-af43-603852e9ee25
32 lines
865 B
Text
32 lines
865 B
Text
|
|
fn = "<grep -a ^H ".ARG1
|
|
|
|
set y2tics
|
|
set ytics nomirror
|
|
set ylab "Temperature [°C]"
|
|
set y2lab "Voltage [V], Bias Current [10nA]"
|
|
set xlab "Time"
|
|
set y2ra [0:]
|
|
set yra [0<*:*]
|
|
|
|
R1 = 3.3e3
|
|
R25 = 3.3e3
|
|
B25 = 4500.
|
|
R(a) = R1*a/(4096-a)
|
|
degC(a) = B25/(log(R(a)/R25)+B25/298.0) - 273
|
|
|
|
t0=`date +%s -d 0`
|
|
t(x) = (x-t0)/3600.0
|
|
t(x)=x
|
|
set format x "%H:%M\n%d. %b\n%Y" time
|
|
|
|
plot \
|
|
fn u (t($2)):($3*3.3/4096) axis x1y2 tit "V_{CORE}" w l, \
|
|
fn u (t($2)):($4*9.9/4096) axis x1y2 tit "V_{CC}" w l, \
|
|
fn u (t($2)):($5*6.6/4096) axis x1y2 tit "V_{IO}" w l, \
|
|
fn u (t($2)):($6*6.6/4096) axis x1y2 tit "V_{PRIM}" w l, \
|
|
fn u (t($2)):(degC($7)) axis x1y1 tit "T_{FPGA}" w l, \
|
|
fn u (t($2)):(degC($8)) axis x1y1 tit "T_{1}" w l, \
|
|
fn u (t($2)):(degC($9)) axis x1y1 tit "T_{2}" w l, \
|
|
fn u (t($2)):($10*0.077/10) axis x1y2 tit "I_{BIAS}" w l
|
|
|