mirror of
https://codeberg.org/ET-Kiel/C-V.git
synced 2026-06-28 03:09:49 +02:00
39 lines
1 KiB
Text
39 lines
1 KiB
Text
#!/usr/local/bin/gnuplot
|
||
|
||
fn="prohepam-190782-II"
|
||
|
||
set xlabel "V_{BIAS} [V]"
|
||
set ylabel "C_{DET} [pF]"
|
||
A(x)=column("Vout")/column("Vin")*11/sin(column("phi")*pi/180)
|
||
B(x)=1/(1 - 1/(2*pi*column("f")*10e-9*909e3))
|
||
C(x)=1e12/2/pi/column("f")/909e3-Coff
|
||
|
||
Coff = 288+50
|
||
Ath=900e-6 # m²
|
||
eps0 = 8.8542 # pF/m
|
||
eps = 11.68
|
||
d = 500e-6 # m
|
||
Cth(V, Vdep) = eps*eps0*Ath/d * (V>Vdep ? 1 : 1/sqrt(V/Vdep))
|
||
|
||
set y2tics
|
||
set ytics nomirror
|
||
set y2lab "I_{BIAS} [nA]"
|
||
|
||
unset log y2
|
||
set log y
|
||
set log x
|
||
|
||
set xra [5:120]
|
||
set y2ra [0:10]
|
||
|
||
|
||
## Last datafile plotted: "seth-hetab4.cv"
|
||
set title fn
|
||
set grid mxtics mytics xtics ytics
|
||
set key center top
|
||
plot "<sort -n ".fn.".cv" u "Vbias":"Ibias" axis x1y2 tit "I_{BIAS}" w lp pt 5, \
|
||
"" u "Vbias":(C(1)/A(1)*B(1)) tit "C(ω)×B(ω)/A(a,φ)" with lp pt 7, \
|
||
"" u "Vbias":(C(1)/A(1)) tit "C(ω)/A(a,φ)" with lp pt 6, \
|
||
"" u "Vbias":(C(1)*B(1)) tit "C(ω)×B(ω)" with lp pt 6, \
|
||
"" u "Vbias":(C(1)) tit "C(ω)" with lp pt 6, \
|
||
for [Vdep=50:70:10] Cth(x,0+Vdep) tit sprintf("V_{DEP} = %.0fV", Vdep)
|